for the HP 42S
Differential impedance of an edge coupled stripline
Usage
[SOLVER] [ZdSL]
Variables 
MEM "Zd"	: Differential impedance [Ω]
MEM "E"		: Relative permitivity
MEM "H"		: Height [mm]
MEM "T"		: Thickness [mm]
MEM "W"		: Width [mm]
MEM "S"		: Side gap [mm]
Program list
To be used in the SOLVER 
00 { 97-Byte Prgm }
01>LBL "ZdSL"
02 MVAR "Zd"
03 MVAR "E"
04 MVAR "H"
05 MVAR "T"
06 MVAR "W"
07 MVAR "S"
08 -2.9    
09 RCL× "S"
10 RCL "H" 
11 ENTER   
12 +       
13 RCL+ "T"
14 ÷
15 E^X     
16 -0.347  
17 × 
18 1       
19 +       
20 120     
21 × 
22 RCL "E" 
23 SQRT    
24 ÷
25 RCL "H" 
26 ENTER   
27 +       
28 RCL+ "T"
29 1.9     
30 × 
31 0.8     
32 RCL× "W"
33 RCL+ "T"
34 ÷
35 LN      
36 × 
37 RCL- "Zd"
38 RTN     
39 END
Formulas used
Zd = 120/sqrt(er)*log(1.9 * (2*h + t) / (0.8*w + t))*(1 - 0.347*exp(-2.9*s>/(2*h + t)))
    Valid for 0.1 ≤ w/h ≤ 2 and t/h ≤ 0.25
where,
        Zo	: single ended impedance
        Zd	: differential impedance
        er	: relative permitivity
        h	: height of the dielectric [μm]
        s	: side gap between the conductors [μm]
        t	: thickness of the conductor [μm]
        w	: width of the conductor [μm]
Example 
Zd = 99.5083687432
E  = 4.7
H  = 0.2
T  = 0.018
W  = 0.1
S  = 0.13
REFERENCE
  1. Brian C. Wadell, "Transmission line design handbook", Artech House, Boston, May 31 1991, ISBN 0-89006-436-9
  2. Howard Johnson, Martin Graham, "High Speed Digital Design: A Handbook of Black Magic", Pretice hall, April 18 1993, ISBN 0-13-395724-1
SEE ALSO
Online calculator - Differential impedance of an edge coupled stripline
Copyright (c) Hosoda Takayuki. All rights reserved.
Powered by
 Finetune