Using italic, bold, upper, lower letter and degree charactor ° with gnuplot

gnuplot での ISO 8601 フォーマットの時刻データの読み込み例 (postscript 出力）

gnuplot で ISO 8601 の基本形式の日付・時刻を含むデータファイルの扱い方を紹介します。

プロット例

プロットファイル例 rsq.plt

#!/gnuplot
reset
set encoding iso_8859_1
set grid
set style data linespoints
set title "Sheet resistance of the trace of the gel pen vs. elapsed time ({/Helvetica-Oblique T}_{a} {/Symbol \273} 23 \260C, DUT: FC)"
set xlabel "elapsed time {/Helvetica-Oblique t}_{e} [hour]"
set xtics 24
set xrange[0:336]
set ylabel "sheet resistance {/Helvetica-Oblique R}_{sq} [{/Symbol \264} 10^6 {/Symbol W}]"
set logscale y
set ytics add (2, 3, 4, 5, 20, 50, 200, 500, 600)
set yrange[1: 1000]
set label 1 at 25, 655 "Upper Limit of Resistance Measurement" textcolor rgb "orange"
t0 = strptime("%Y%m%d%H%M", "202412300340")
set timefmt "%Y%m%d\124%H%M" # \124 represents the letter 'T' in octal format.
set terminal postscript solid color enhanced 12
set output "rsq.ps"
plot "rsq.dat" u (timecolumn(1) - t0) / 3600 : 2 t "{/Helvetica-Oblique R}_{sq}"
set output

gnuplot 4.6, 5.4p8 で確認

データファイル例 rsq.dat

# ISO 8601 format
# YYYYmmddTHHMM	R_sq	Ta 
20241230T0340	600	23
20241230T0740	102	23
20241230T0940	75.0	23
20241231T0330	16.0	23
20250103T0134	6.27	23
20250104T0540	5.56	23
20250105T0147	4.87	23
20250106T0108	4.52	23
20250110T0742	3.49	23
20250112T0737	3.23	23
20250113T1254	3.26	23

Freqently used symbols:

° : \260

α : {/Symbol a}

β : {/Symbol b}

γ : {/Symbol g}

δ : {/Symbol d}

Δ : {/Symbol D}

ε : {/Symbol-Oblique e}

η : {/Symbol-Oblique h}

θ : {/Symbol-Oblique q}

λ : {/Symbol-Oblique l}

μ : {/Symbol m}

ω : {/Symbol-Oblique o}

π : {Symbol p}

σ : {/Symbol s}

Ω : {/Symbol W}

Φ : {/Symbol-Oblique P}

ζ : {Symbol z}

χ : {Symbol c}

≤ : {/Symbol \243}

∞ : {/Symbol \245}

↔ : {/Symbol \253}

← : {/Symbol \254}

↑ : {/Symbol \255}

→ : {/Symbol \256}

↓ : {/Symbol \257}

± : {/Symbol \261}

≥ : {/Symbol \263}

× : {/Symbol \264}

∂ : {/Symbol \266}

≠ : {/Symbol \271}

≈ : {/Symbol \273}

√ : {/Symbol \326}

REFERENCE

ISO 8601 — Wikipedia