Using greek letter with gnuplot

gnuplot でのギリシア文字の使用例（標準偏差, postscript 出力）

set title "Standard normal distribution"
set label 1 "68.27% are within {/Symbol \261s}" at 0, 0.25197, 0
set label 2 "95.45% are within {/Symbol \2612s}" at 0, 0.06399, 0
set label 3 "99.73% are within {/Symbol \2613s}" at 0, 0.01, 0
set label 4 "99.90% are within {/Symbol \2613.3s}" at 0,-0.04399, 0
set arrow 1 from -1.0, 0.24197, 0 to 1, 0.24197, 0 heads back filled linetype -1
set arrow 2 from -2.0, 0.05399, 0 to 2, 0.05399, 0 heads back filled linetype -1
set arrow 3 from -3.0, 0.00000, 0 to 3, 0, 0 heads back filled linetype -1
set arrow 4 from -3.3, -0.05399, 0 to 3.3, -0.05399, 0 heads back filled linetype -1
set xrange [ -3.5 : 3.5 ]
set xtics   ("" -3.3, "{/Symbol m-3s}" -3, "{/Symbol m-2s}" -2, "{/Symbol m-s}" -1, "{/Symbol m}" 0, "{/Symbol m+s}" 1, "{/Symbol m+2s}" 2, "{/Symbol m+3s}" 3, "" 3.3)
set ylabel "Probability density"
set yrange [ -0.09: 0.44] 
set terminal postscript solid color font "Arial, 15" enhanced
set output "normal-distribution.ps" ;
f(x)=exp(-x*x/2)/sqrt(2*pi)
plot f(x) lw 2 t "Probability density" 
set output

Freqently used symbols:

° : \260

α : {/Symbol a}

β : {/Symbol b}

γ : {/Symbol g}

δ : {/Symbol d}

Δ : {/Symbol D}

ε : {/Symbol-Oblique e}

η : {/Symbol-Oblique h}

θ : {/Symbol-Oblique q}

λ : {/Symbol-Oblique l}

μ : {/Symbol m}

ω : {/Symbol-Oblique o}

π : {Symbol p}

σ : {/Symbol s}

Ω : {/Symbol W}

Φ : {/Symbol-Oblique P}

ζ : {Symbol z}

χ : {Symbol c}

≤ : {/Symbol \243}

∞ : {/Symbol \245}

↔ : {/Symbol \253}

← : {/Symbol \254}

↑ : {/Symbol \255}

→ : {/Symbol \256}

↓ : {/Symbol \257}

± : {/Symbol \261}

≥ : {/Symbol \263}

× : {/Symbol \264}

∂ : {/Symbol \266}

≠ : {/Symbol \271}

≈ : {/Symbol \273}

√ : {/Symbol \326}

SEE ALSO