for the HP 42S
uZw - Synthesize/Analyze Microstrip transmission line
Japanese Japanese edition is here.


Usage

Synthesize	: [XEQ] Z→W
Analyze  	: [XEQ] W→Z
Zo→Zdiff		: [XEQ] ZD

Parameters

Var "E" : relative permittivity			(W→Z, Z→W)
Var "H" : dielectric height           [mm]	(Zo→Zdiff)
Var "S" : side gap                    [mm]	(Zo→Zdiff)
Var "T" : conductor thickness         [mm]	(W→Z, Z→W)
Var "W" : microstripline width        [mm]	(W→Z)
Var "Z" : charactoristic impedance    [Ω]	(Z→W, Zo→Zdiff)

Resources used

Var "E" : relative permittivity
Var "H" : dielectric height           [mm]
Var "S" : side gap                    [mm]
Var "T" : conductor thickness         [mm]
Var "P" : work/velocity of propagation  
Var "W" : microstripline width        [mm]
Var "Z" : charactoristic impedance    [Ω]
Flag 88 : will be cleared

Output

Var "P" : velocity of propagation  
Var "W" : microstripline width        [mm] (Synthesized)
Var "Z" : charactoristic impedance    [Ω] (Analyzed)

Reg t: open end compensation          [mm]
Reg z: rightangle bend compensation
Reg y: velocity of propagation
Reg X: microstrip line width          [mm] (Synthesized)
     | Characteristic impedance       [Ω] (Analyzed)

Program list

uZW - Rev 1.8: Jun. 5 2017 - Copyright(c) 1998-2017 Takayuki HOSODA, All rights reserved.
Synthesis Effective width Characteristic impedance Velocity of
propagation
Open-end compensation Rightangle bend
compensation
Display results Analyze Coefficient Differential
impedance
00 { 517-Byte Prgm }
01 LBL "Z→W"
02 MVAR "Z"
03 MVAR "E"
04 MVAR "H"
05 MVAR "T"
06 MVAR "W"
07 VARMENU "Z→W"
08 STOP
09 EXITALL
10 RCL "Z"
11 XEQ C
12 ÷
13 E↑X
14 1
15 -
16 STO "P"
17 10
18 RCL× "H"
19 0.6
20 RCL+ "E"
21 SQRT
22 RCL× "Z"
23 69
24 ÷
25 E↑X
26 ÷
27 STO "W"
28 RCL- "T"
29 CF 88
30 PGMSLV "uX"
31 SOLVE "W"
32 XEQ B
33 RCL "W"
34 RTN
35 LBL "uX"
36 4
37 RCL× "H"
38 RCL "H"
39 1.1
40 RCL× "T"
41 RCL+ "W"
42 PI
43 ×
44 ÷
45 X^2
46 1
47 +
48 SQRT
49 RCL× "T"
50 ÷
51 LN
52 1
53 +
54 RCL× "T"
55 PI
56 ÷
57 RCL "E"
58 ENTER
59 +
60 1/X
61 0.5
62 +
63 ×
64 LASTX
65 PI
66 X^2
67 4
68 R↑
69 RCL+ "W"
70 ÷
71 RCL× "H"
72 ENTER
73 R↓
74 R↓
75 ×
76 8
77 RCL÷ "E"
78 14
79 +
80 11
81 ÷
82 R↑
83 ×
84 ENTER
85 R↓
86 X^2
87 +
88 SQRT
89 R↑
90 +
91 ×
92 FS?C 88
93 GTO A
94 RCL÷ "P"
95 1
96 -
97 CLA
98 "W:"
99 ARCL "W"
100 AVIEW
101 RTN
102 LBL A
103 1
104 +
105 LN
106 XEQ C
107 ×
108 RTN
109 LBL B
110 1
111 X<> "E"
112 STO "P"
113 SF 88
114 XEQ "uX"
115 RCL÷ "Z"
116 1/X
117 X<> "P"
118 STO "E"
119 0.3
120 RCL "P"
121 X↑2
122 1/X
123 +
124 LASTX
125 0.258
126 -
127 ÷
128 0.262
129 RCL "W"
130 RCL÷ "H"
131 +
132 LASTX
133 0.813
134 +
135 ÷
136 ×
137 0.412
138 ×
139 RCX× "H"
140 ENTER
141 ENTER
142 -1.35
143 RCL× "W"
144 RCL÷ "H"
145 E↑X
146 0.65
147 ×
148 0.52
149 +
150 X≤0?
151 CLX
152 RCL "P"
153 CLA
154 ENG 03
155 "Z="
156 ARCL "Z"
157 ",W="
158 ARCL "W"
159 "v="
160 ARCL "P"
161 ",c="
162 ARCL ST Y
163 AVIEW
164 ENG 11
165 RTN
166 LBL "W→Z"
167 MVAR "W"
168 MVAR "E"
169 MVAR "H"
170 MVAR "T"
171 MVAR "Z"
172 VARMENU "W→Z"
173 STOP
174 EXITALL
175 SF 88
176 XEQ "uX"
177 STO "Z"
178 XEQ B
179 RCL "Z"
180 RTN
181 LBL C
182 42.397056
183 1
184 RCL+ "E"
185 SQRT
186 ÷
187 RTN
188 LBL "ZD"
189 MVAR "Z"
190 MVAR "S"
191 MVAR "H"
192 VARMENU "ZD"
193 STOP
194 EXITALL
195 RCL "S"
196 RCL÷ "H"
197 -0.96
198 ×
199 E↑X
200 -0.48
201 ×
202 1
203 +
204 RCL× "Z"
205 ENTER
206 +
207 CLA
208 ENG 03
209 "Zd="
210 ARCL ST X
211 ",S="
212 ARCL "S"
213 "W="
214 ARCL "W"
215 ",H="
216 ARCL "H"
217 AVIEW
218 ENG 11
219 RTN
220 END
"Z→W"
Synthsize Microstrip line
"W→Z"
Analyze Microstrip line
"μX"
The sub-routine to calculate the transmission line impedance (error ≤ 2%[1])
"ZD"
Differential impedance of the microstrip line pair[3]
The practical ranges for Zo and Zdiff are from 20Ω to about 150Ω with possible errors of up to ±10%.
B
The sub-routine to calculate velocity of propagation, open end compensation and rightangle bend compensation.
(0.25 ≤ W/H≤ 2.75, 2.5 ≤ εr ≤ 25, VSWR ≤ 1.1 [2](i.e. S11 ≤ -26dB))

Download

uZW : 'Z→W uX W→Z' (ustrip-1.8.raw, 520 byte, raw program file for the Free42)

Formulas used

Micro-strip-line characteristic impedance
where,

w_\mathrm{eff}  & \simeq & w + t \frac{1 + \displaystyle\frac{1}{\varepsilon_\mathrm{r}}}{2 \pi}\left(1 + \ln \left(
\frac{4}{ \sqrt{\left(\displaystyle\frac{t}{h}\right)^2
+\left(\displaystyle\frac{1}{\pi}\frac{1}{\displaystyle\frac{w}{t} + 1.1}\right)^2} }
\right)\right)

Open end effect length
Open end effect length
Rightangle bend compensation

R_\mathrm{miter} & = &  0.52 + 0.65 \ e^{\displaystyle\left(\frac{-1.35\  w}{h} \right)}
Differencial impedance of side coupled microstrip line

Z_\mathrm{diff} $ \simeq $ Z_0 \left(1 - 0.48\ e^{\left(\displaystyle\frac{-0.96 s}{h}\right)} \right)

Example (Z→W : Synthesis)

Input
Var "Z" = 50               [Ω]
Var "E" = 4.5
Var "H" = 0.200            [mm]
Var "T" = 0.018            [mm]
Var "W" =                  [mm]
Output

Reg t : 77.0125481499e-3 [mm] Reg z : 577.860580911e-3 Reg y : 553.140318922e-3 Reg X : 358.360892363e-3 [mm]

REFERENCES

  1. H. A. Wheeler, "Transmission-line properties of a strip on a dielectric sheet on a plane", IEEE Trans. Microwave Theory Tech., vol. MTT-25, pp.631-647, Aug. 1977.
  2. R. J. Douville and D. S. James, "Experimental study of symmetric microstrip bends and their compensation", IEEE Trans. Microwave Theory Tech., vol. MTT-26, pp. 175-182, Mar. 1978
  3. James A. Mears, "Transmission Line RAPIDESIGNER Operation and Applications Guide", National Semiconductor Application Note, AN-905, May.1996

SEE ALSO

Online calculator - Synthsize/Analyze microstrip transmission line
for the HP 15C - Synthsize/Analyze microstrip transmission line
for the HP 32sII - Synthsize/Analyze microstrip transmission line
Ostrowski's method

www.finetune.co.jp [Mail] © 2000 Takayuki HOSODA.
Powered by
 Finetune